Add syntax snippets

modules/ROOT/content-nav.adoc

@@ -154,6 +154,7 @@
 *** xref:appendix/gql-conformance/supported-optional.adoc[]
 *** xref:appendix/gql-conformance/analogous-cypher.adoc[]
 *** xref:appendix/gql-conformance/additional-cypher.adoc[]
+** xref:appendix/grammar/index.adoc[]
 ** xref:appendix/tutorials/index.adoc[]
 *** xref:appendix/tutorials/basic-query-tuning.adoc[]
 *** xref:appendix/tutorials/advanced-query-tuning.adoc[]

modules/ROOT/examples/syntax/clauses/call-procedure.bnf

@@ -0,0 +1,2 @@
+<call procedure statement> ::= 
+  [ "OPTIONAL" ] "CALL" <procedure call>

modules/ROOT/examples/syntax/clauses/create.bnf

@@ -0,0 +1,2 @@
+<create statement> ::= 
+  "CREATE" <create graph pattern>

modules/ROOT/examples/syntax/clauses/delete.bnf

@@ -0,0 +1,2 @@
+<delete statement> ::= 
+  [ "DETACH" | "NODETACH" ] "DELETE" <delete item list>

modules/ROOT/examples/syntax/clauses/filter.bnf

@@ -0,0 +1,2 @@
+<filter statement> ::= 
+  "FILTER" [ "WHERE" ] <search condition>

modules/ROOT/examples/syntax/clauses/foreach.bnf

@@ -0,0 +1,2 @@
+<foreach statement> ::= 
+  "FOREACH" "(" <foreach element source> <foreach action> ")"

modules/ROOT/examples/syntax/clauses/let.bnf

@@ -0,0 +1,2 @@
+<let statement> ::= 
+  "LET" <let variable definition list>

modules/ROOT/examples/syntax/clauses/limit.bnf

@@ -0,0 +1,2 @@
+<limit clause> ::= 
+  "LIMIT" <value expression>

modules/ROOT/examples/syntax/clauses/load-csv.bnf

@@ -0,0 +1,2 @@
+<load csv statement> ::= 
+  "LOAD CSV" [ "WITH HEADERS" ] <csv source> [ <csv field terminator> ]

modules/ROOT/examples/syntax/clauses/match.bnf

@@ -0,0 +1,12 @@
+<simple match statement> ::= 
+  "MATCH" <graph pattern>
+
+<graph pattern> ::= 
+  [ <match mode> ] <path pattern> [ { "," <path pattern> }... ] [ <graph pattern where clause> ]
+
+<match mode> ::= 
+    "REPEATABLE" { "ELEMENT" [ "BINDINGS" ] | "ELEMENTS" }
+  | "DIFFERENT" { "RELATIONSHIP" [ "BINDINGS" ] | "RELATIONSHIPS" }
+
+<path pattern> ::= 
+  [ <identifier> "=" ] [ <path pattern prefix> ] <path pattern expression>

modules/ROOT/examples/syntax/clauses/merge.bnf

@@ -0,0 +1,2 @@
+<merge statement> ::= 
+  "MERGE" <merge graph pattern> [ <merge action> ]

modules/ROOT/examples/syntax/clauses/optional-match.bnf

@@ -0,0 +1,2 @@
+<optional match statement> ::= 
+  "OPTIONAL" <optional match operand>

modules/ROOT/examples/syntax/clauses/order-by.bnf

@@ -0,0 +1,2 @@
+<order by clause> ::= 
+  "ORDER BY" <sort specification list>

modules/ROOT/examples/syntax/clauses/remove.bnf

@@ -0,0 +1,2 @@
+<remove statement> ::= 
+  "REMOVE" <remove item list>

modules/ROOT/examples/syntax/clauses/return.bnf

@@ -0,0 +1,2 @@
+<return statement> ::= 
+  "RETURN" <return statement body> [ <order by and page clause> ]

modules/ROOT/examples/syntax/clauses/set.bnf

@@ -0,0 +1,2 @@
+<set statement> ::= 
+  "SET" <set item list>

modules/ROOT/examples/syntax/clauses/show-functions.bnf

@@ -0,0 +1,9 @@
+<show functions statement> ::= 
+  "SHOW" [ "ALL" | "BUILT IN" | "USER DEFINED" ] { "FUNCTION" | "FUNCTIONS" } [ <executable by> ] [ <show result clause> ]
+
+<executable by> ::= 
+  "EXECUTABLE" [ "BY CURRENT USER" | "BY" <user name> ]
+
+<show result clause> ::= 
+    "YIELD" <yield item list> [ <order by clause> ] [ <offset clause> ] [ <limit clause> ] [ <where clause> ] [ <return statement> ]
+  | <where clause>

modules/ROOT/examples/syntax/clauses/show-procedures.bnf

@@ -0,0 +1,2 @@
+<show procedures statement> ::= 
+  "SHOW" <procedure keywords> [ <executable by> ] [ <show result clause> ]

modules/ROOT/examples/syntax/clauses/show-settings.bnf

@@ -0,0 +1,2 @@
+<show settings statement> ::= 
+  "SHOW" <setting keywords> [ <character string list element list or expression> ] [ <show result clause> ]

modules/ROOT/examples/syntax/clauses/show-transactions.bnf

@@ -0,0 +1,6 @@
+<show transactions statement> ::= 
+  "SHOW" { "TRANSACTION" | "TRANSACTIONS" } [ <character string list element list or expression> ] [ <show result clause> ]
+
+<show result clause> ::= 
+    "YIELD" <yield item list> [ <order by clause> ] [ <offset clause> ] [ <limit clause> ] [ <where clause> ] [ <return statement> ]
+  | <where clause>

modules/ROOT/examples/syntax/clauses/skip.bnf

@@ -0,0 +1,2 @@
+<offset clause> ::= 
+  <offset synonym> <value expression>

modules/ROOT/examples/syntax/clauses/terminate-transactions.bnf

@@ -0,0 +1,5 @@
+<terminate transaction statement> ::= 
+  "TERMINATE" { "TRANSACTION" | "TRANSACTIONS" } <character string list element list or expression> [ <show yield result clause> ]
+
+<show yield result clause> ::= 
+  "YIELD" <yield item list> [ <order by clause> ] [ <offset clause> ] [ <limit clause> ] [ <where clause> ] [ <return statement> ]

modules/ROOT/examples/syntax/clauses/unwind.bnf

@@ -0,0 +1,2 @@
+<unwind statement> ::= 
+  "UNWIND" <value expression> "AS" <binding variable>

modules/ROOT/examples/syntax/clauses/use.bnf

@@ -0,0 +1,2 @@
+<use graph clause> ::= 
+  "USE" <graph expression>

modules/ROOT/examples/syntax/clauses/where.bnf

@@ -0,0 +1,2 @@
+<where clause> ::= 
+  "WHERE" <search condition>

modules/ROOT/examples/syntax/clauses/with.bnf

@@ -0,0 +1,2 @@
+<with statement> ::= 
+  "WITH" <return statement body> [ <order by and page clause> ] [ <where clause> ]

modules/ROOT/examples/syntax/constraints/create.bnf

@@ -0,0 +1,62 @@
+<create constraint statement> ::= 
+  "CREATE CONSTRAINT" [ <constraint name> | <general parameter reference> ] [ "IF NOT EXISTS" ] <constraint specification> [ <command options> ]
+
+<command options> ::= 
+  "OPTIONS" <map value or parameter specification>
+
+<property names specification> ::= 
+    <property name specification>
+  | "(" <property name specification> [ { "," <property name specification> }... ] ")"
+
+<property name specification> ::= 
+  <binding variable> "." <property name>
+
+<constraint specification> ::= 
+    <node constraint specification>
+  | <relationship constraint specification>
+
+<node constraint specification> ::= 
+    <node key constraint>
+  | <node uniqueness constraint>
+  | <node property existence constraint>
+  | <node property type constraint>
+
+<relationship constraint specification> ::= 
+    <relationship key constraint>
+  | <relationship uniqueness constraint>
+  | <relationship property existence constraint>
+  | <relationship property type constraint>
+
+<node key constraint> ::= 
+  "FOR" <command node pattern> "REQUIRE" <property names specification> "IS" [ "NODE" ] "KEY"
+
+<node uniqueness constraint> ::= 
+  "FOR" <command node pattern> "REQUIRE" <property names specification> "IS" [ "NODE" ] "UNIQUE"
+
+<node property existence constraint> ::= 
+  "FOR" <command node pattern> "REQUIRE" <property name specification> "IS NOT NULL"
+
+<node property type constraint> ::= 
+  "FOR" <command node pattern> "REQUIRE" <property name specification> { [ "IS" ] "::" | "IS TYPED" } <value type>
+
+<relationship key constraint> ::= 
+  "FOR" <command relationship pattern> "REQUIRE" <property names specification> "IS" [ "RELATIONSHIP" | "REL" ] "KEY"
+
+<relationship uniqueness constraint> ::= 
+  "FOR" <command relationship pattern> "REQUIRE" <property names specification> "IS" [ "RELATIONSHIP" | "REL" ] "UNIQUE"
+
+<relationship property existence constraint> ::= 
+  "FOR" <command relationship pattern> "REQUIRE" <property name specification> "IS NOT NULL"
+
+<relationship property type constraint> ::= 
+  "FOR" <command relationship pattern> "REQUIRE" <property name specification> { [ "IS" ] "::" | "IS TYPED" } <value type>
+
+<command node pattern> ::= 
+  "(" <binding variable> ":" <label name> ")"
+
+<command relationship pattern> ::= 
+  "()" { "<-[" <binding variable> ":" <label name> "]-" | "-[" <binding variable> ":" <label name> "]->" | "<-[" <binding variable> ":" <label name> "]->" | "-[" <binding variable> ":" <label name> "]-" } "()"
+
+<map value or parameter specification> ::= 
+    <map value constructor>
+  | <general parameter reference>

modules/ROOT/examples/syntax/constraints/drop.bnf

@@ -0,0 +1,6 @@
+<drop constraint statement> ::= 
+  "DROP CONSTRAINT" <constraint name specification> [ "IF EXISTS" ]
+
+<constraint name specification> ::= 
+    <constraint name>
+  | <general parameter reference>

modules/ROOT/examples/syntax/constraints/show.bnf

@@ -0,0 +1,24 @@
+<show constraints statement> ::= 
+  "SHOW" [ <show constraint type> ] <constraint keywords> [ <show result clause> ]
+
+<show constraint type> ::= 
+    <show all constraints>
+  | <show key constraints>
+  | <show uniqueness constraints>
+  | <show property existence constraints>
+  | <show property type constraints>
+
+<show all constraints> ::= 
+  "ALL"
+
+<show key constraints> ::= 
+  [ "NODE" | "RELATIONSHIP" | "REL" ] "KEY"
+
+<show uniqueness constraints> ::= 
+  [ "NODE" | "RELATIONSHIP" | "REL" ] [ "PROPERTY" ] { "UNIQUENESS" | "UNIQUE" }
+
+<show property existence constraints> ::= 
+  [ "NODE" | "RELATIONSHIP" | "REL" ] [ "PROPERTY" ] { "EXISTENCE" | "EXIST" }
+
+<show property type constraints> ::= 
+  [ "NODE" | "RELATIONSHIP" | "REL" ] "PROPERTY TYPE"