vault-base-setup/provider.tf at main · stuttgart-things/vault-base-setup · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
terraform {
  required_version = ">= 1.10.0"

  required_providers {
    kubernetes = {
      source  = "hashicorp/kubernetes"
      version = ">= 2.24.0"
    }

    kubectl = {
      source  = "gavinbunney/kubectl"
      version = ">= 1.14.0"
    }

    vault = {
      source  = "hashicorp/vault"
      version = ">= 3.21.0"
    }

    helm = {
      source  = "hashicorp/helm"
      version = ">= 2.12.1"
    }

    local = {
      source  = "hashicorp/local"
      version = "2.8.0"
    }

    null = {
      source  = "hashicorp/null"
      version = ">= 3.2.0"
    }
  }
}

provider "kubernetes" {
  config_context = var.kubeconfig_content == null ? var.context : null
  config_path    = var.kubeconfig_path

  host                   = var.kubeconfig_content != null ? local.kubeconfig.clusters[0].cluster.server : null
  cluster_ca_certificate = var.kubeconfig_content != null ? base64decode(local.kubeconfig.clusters[0].cluster["certificate-authority-data"]) : null
  client_certificate     = var.kubeconfig_content != null ? base64decode(local.kubeconfig.users[0].user["client-certificate-data"]) : null
  client_key             = var.kubeconfig_content != null ? base64decode(local.kubeconfig.users[0].user["client-key-data"]) : null
}

provider "kubectl" {
  config_context   = var.kubeconfig_content == null ? var.context : null
  config_path      = var.kubeconfig_path
  load_config_file = var.kubeconfig_content == null

  host                   = var.kubeconfig_content != null ? local.kubeconfig.clusters[0].cluster.server : null
  cluster_ca_certificate = var.kubeconfig_content != null ? base64decode(local.kubeconfig.clusters[0].cluster["certificate-authority-data"]) : null
  client_certificate     = var.kubeconfig_content != null ? base64decode(local.kubeconfig.users[0].user["client-certificate-data"]) : null
  client_key             = var.kubeconfig_content != null ? base64decode(local.kubeconfig.users[0].user["client-key-data"]) : null
}

provider "helm" {
  kubernetes = {
    config_path    = var.kubeconfig_path
    config_context = var.kubeconfig_content == null ? var.context : null

    host                   = var.kubeconfig_content != null ? local.kubeconfig.clusters[0].cluster.server : null
    cluster_ca_certificate = var.kubeconfig_content != null ? base64decode(local.kubeconfig.clusters[0].cluster["certificate-authority-data"]) : null
    client_certificate     = var.kubeconfig_content != null ? base64decode(local.kubeconfig.users[0].user["client-certificate-data"]) : null
    client_key             = var.kubeconfig_content != null ? base64decode(local.kubeconfig.users[0].user["client-key-data"]) : null
  }
}

provider "vault" {
  address         = var.vault_addr
  skip_tls_verify = var.skip_tls_verify
}