test: add cmake packaging unit tests

Author: ahoarau

test/cmake-packaging/CMakeLists.txt

@@ -0,0 +1,27 @@
+add_test(
+    NAME simde-cmake-install
+    COMMAND ${CMAKE_CTEST_COMMAND}
+        --build-and-test "${PROJECT_SOURCE_DIR}"
+                         "${PROJECT_BINARY_DIR}/build"
+        --build-generator ${CMAKE_GENERATOR}
+        --build-target install
+        --build-options "-DCMAKE_INSTALL_PREFIX=${PROJECT_BINARY_DIR}/install"
+)
+
+add_test(
+    NAME simde-cmake-find-package
+    COMMAND ${CMAKE_CTEST_COMMAND}
+    --build-and-test "${CMAKE_CURRENT_SOURCE_DIR}/cmake-find-package"
+                     "${PROJECT_BINARY_DIR}/cmake-find-package/build"
+    --build-generator "${CMAKE_GENERATOR}"
+    --build-options "-DCMAKE_PREFIX_PATH=${PROJECT_BINARY_DIR}/install"
+)
+set_tests_properties(simde-cmake-find-package PROPERTIES DEPENDS simde-cmake-install)
+
+add_test(
+    NAME simde-cmake-fetchcontent
+    COMMAND ${CMAKE_CTEST_COMMAND}
+    --build-and-test "${CMAKE_CURRENT_SOURCE_DIR}/cmake-fetchcontent"
+                     "${PROJECT_BINARY_DIR}/cmake-fetchcontent/build"
+    --build-generator "${CMAKE_GENERATOR}"
+)

test/cmake-packaging/cmake-fetchcontent/CMakeLists.txt

@@ -0,0 +1,16 @@
+cmake_minimum_required(VERSION 3.22)
+project(simde-fetchcontent-consumer LANGUAGES C CXX)
+
+include(FetchContent)
+FetchContent_Declare(simde SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/../../../)
+FetchContent_MakeAvailable(simde)
+
+add_executable(consumer-fc-c main.c)
+target_link_libraries(consumer-fc-c PRIVATE simde::simde)
+
+add_executable(consumer-fc-cpp main.cpp)
+target_link_libraries(consumer-fc-cpp PRIVATE simde::simde)
+
+enable_testing()
+add_test(NAME consumer-fc-c COMMAND consumer-fc-c)
+add_test(NAME consumer-fc-cpp COMMAND consumer-fc-cpp)

test/cmake-packaging/cmake-fetchcontent/main.c

@@ -0,0 +1,9 @@
+#include <simde/x86/sse.h>
+#include <stdio.h>
+
+int main(void) {
+  simde__m128 a = simde_mm_set_ps(1.0f, 2.0f, 3.0f, 4.0f);
+  (void)a;
+  printf("SIMDe cmake FetchContent test works!\n");
+  return 0;
+}

test/cmake-packaging/cmake-fetchcontent/main.cpp

@@ -0,0 +1,9 @@
+#include <iostream>
+#include <simde/x86/sse.h>
+
+int main() {
+  simde__m128 a = simde_mm_set_ps(1.0f, 2.0f, 3.0f, 4.0f);
+  (void)a;
+  std::cout << "SIMDe cmake install test works (C++)!" << std::endl;
+  return 0;
+}

test/cmake-packaging/cmake-find-package/CMakeLists.txt

@@ -0,0 +1,15 @@
+cmake_minimum_required(VERSION 3.22)
+project(simde-consumer LANGUAGES C CXX)
+
+find_package(simde CONFIG REQUIRED)
+message(STATUS "simde version: ${simde_VERSION}")
+
+add_executable(consumer-c main.c)
+target_link_libraries(consumer-c PRIVATE simde::simde)
+
+add_executable(consumer-cpp main.cpp)
+target_link_libraries(consumer-cpp PRIVATE simde::simde)
+
+enable_testing()
+add_test(NAME consumer-c COMMAND consumer-c)
+add_test(NAME consumer-cpp COMMAND consumer-cpp)

test/cmake-packaging/cmake-find-package/main.c

@@ -0,0 +1,9 @@
+#include <simde/x86/sse.h>
+#include <stdio.h>
+
+int main(void) {
+  simde__m128 a = simde_mm_set_ps(1.0f, 2.0f, 3.0f, 4.0f);
+  (void)a;
+  printf("SIMDe cmake install test works!\n");
+  return 0;
+}

test/cmake-packaging/cmake-find-package/main.cpp

@@ -0,0 +1,9 @@
+#include <iostream>
+#include <simde/x86/sse.h>
+
+int main() {
+  simde__m128 a = simde_mm_set_ps(1.0f, 2.0f, 3.0f, 4.0f);
+  (void)a;
+  std::cout << "SIMDe cmake install test works (C++)!" << std::endl;
+  return 0;
+}