feat: Enable compiler functionality out of the box in SIL files

Author: alerque

autoload/sile.vim

@@ -0,0 +1,46 @@
+" SPDX-FileCopyrightText: © 2015 Caleb Maclennan <[email protected]>
+" SPDX-License-Identifier: GPL-2.0-or-later
+
+scriptencoding utf-8
+
+if exists('g:loaded_sile')
+  finish
+endif
+
+let g:loaded_sile = 1
+
+if exists('g:sile_no_bin') && g:sile_no_bin
+  unlet! g:sile_bin
+elseif !exists('g:sile_bin') || empty(g:sile_bin)
+  if executable('sile')
+    let g:sile_bin = 'sile'
+  else
+    unlet! g:sile_bin
+    echohl WarningMsg
+    echomsg 'No sile command detected, set g:sile_bin to enable more vim-sile features.'
+    echohl None
+  endif
+elseif !executable(g:sile_bin)
+  unlet! g:sile_bin
+  echohl WarningMsg
+  echomsg 'Command set in g:sile_bin is not executable, fix to to enable more vim-sile features.'
+  echohl None
+endif
+
+if !exists('g:sile_main')
+  let g:sile_main = '%:p'
+endif
+
+function! sile#init() abort
+  if !exists('b:sile_bin')
+    let b:sile_bin = get(g:, 'sile_bin', 0)
+  endif
+  let settings = [
+        \ 'sile_main',
+        \ ]
+  for setting in settings
+    if !has_key(b:, setting)
+      let b:{setting} = get(g:, setting)
+    endif
+  endfor
+endfunction

compiler/sile.vim

@@ -0,0 +1,21 @@
+" SPDX-FileCopyrightText: © 2015 Caleb Maclennan <[email protected]>
+" SPDX-License-Identifier: GPL-2.0-or-later
+
+scriptencoding utf-8
+
+if exists('b:current_compiler')
+  finish
+endif
+
+call sile#init()
+
+let b:current_compiler = b:sile_bin
+
+if exists(':CompilerSet') != 2
+  command -nargs=* CompilerSet setlocal <args>
+endif
+
+let s:escaped_bin = substitute(b:sile_bin, ' ', '\\ ', 'g')
+let s:escaped_main = substitute(shellescape(expand(b:sile_main)), ' ', '\\ ', 'g')
+
+execute 'CompilerSet makeprg=' . s:escaped_bin . '\ ' . s:escaped_main

ftplugin/sile.vim

@@ -13,3 +13,7 @@ let b:did_ftplugin = 1
 
 setlocal comments=:%
 setlocal commentstring=%\ %s
+
+if !exists('current_compiler')
+  compiler sile
+endif