medusa/flake.nix at master · crytic/medusa · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
{
  description = "Medusa smart-contract fuzzer";

  inputs = {
    nixpkgs.url = "nixpkgs/nixos-25.05";
    utils.url = "github:numtide/flake-utils";
    crytic.url = "github:crytic/crytic.nix";
    crytic.inputs.nixpkgs.follows = "nixpkgs";
    crytic.inputs.utils.follows = "utils";
  };

  outputs = inputs: with inputs;
    utils.lib.eachDefaultSystem (system: let
      pkgs = import nixpkgs { inherit system; config.allowUnfree = true; };
    in rec {

      packages = {
        medusa = pkgs.buildGoModule {
          pname = "medusa";
          version = "1.5.1";
          src = ./.;
          vendorHash = "sha256-r4p49cnObkugiEvGZx6bgXhjMbS5tMdfJsAJ7KzWW10=";
          nativeBuildInputs = [
            crytic.packages.${system}.crytic-compile
            crytic.packages.${system}.slither
            pkgs.solc
            pkgs.nodejs
          ];
          doCheck = false; # tests require `npm install` which can't run in hermetic build env
        };
        default = packages.medusa;
      };

      apps = {
        default = {
          type = "app";
          program = "${self.packages.${system}.medusa}/bin/medusa";
        };
      };

      devShells = {
        default = pkgs.mkShell {
          buildInputs = with pkgs; [
            packages.medusa
            bashInteractive
            # runtime dependencies
            crytic.packages.${system}.crytic-compile
            crytic.packages.${system}.slither
            solc
            # test dependencies
            nodejs
            # go development
            go
            gotools
            go-tools
            gopls
            go-outline
            gopkgs
            gocode-gomod
            godef
            golint
            golangci-lint
            # formatting and linting
            dprint
            actionlint
          ];
        };
      };

    }
  );
}