CMakeLists.txt

#
# Copyright (c) 2024 Boost.Yaml Authors
#
# Distributed under the Boost Software License, Version 1.0. (See accompanying
# file LICENSE_1_0.txt or copy at http://www.boost.org/LICENSE_1_0.txt)
#
# Official repository: https://github.com/cppalliance/yaml
#

#-------------------------------------------------
#
# Project
#
#-------------------------------------------------
cmake_minimum_required(VERSION 3.8...3.20)
set(BOOST_YAML_VERSION 1)
if (BOOST_SUPERPROJECT_VERSION)
    set(BOOST_YAML_VERSION ${BOOST_SUPERPROJECT_VERSION})
endif ()
project(boost_yaml VERSION "${BOOST_YAML_VERSION}" LANGUAGES CXX)
set(BOOST_YAML_IS_ROOT OFF)
if (CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR)
    set(BOOST_YAML_IS_ROOT ON)
endif ()
set(__ignore__ ${CMAKE_C_COMPILER})

#-------------------------------------------------
#
# Options
#
#-------------------------------------------------
option(BOOST_YAML_BUILD_TESTS "Build boost::yaml tests even if BUILD_TESTING is OFF" OFF)
option(BOOST_YAML_BUILD_EXAMPLES "Build boost::yaml examples" ${BOOST_YAML_IS_ROOT})
option(BOOST_YAML_WARNINGS_AS_ERRORS "Treat warnings as errors" OFF)

# Check if environment variable BOOST_SRC_DIR is set
if (NOT DEFINED BOOST_SRC_DIR AND DEFINED ENV{BOOST_SRC_DIR})
    set(DEFAULT_BOOST_SRC_DIR "$ENV{BOOST_SRC_DIR}")
else ()
    set(DEFAULT_BOOST_SRC_DIR "${CMAKE_CURRENT_SOURCE_DIR}/../..")
endif ()
set(BOOST_SRC_DIR ${DEFAULT_BOOST_SRC_DIR} CACHE STRING "Boost source dir to use when running CMake from this directory")

#-------------------------------------------------
#
# Boost modules
#
#-------------------------------------------------
# The boost super-project requires one explicit dependency per-line.
set(BOOST_YAML_DEPENDENCIES
        Boost::assert
        Boost::config
        Boost::core
        Boost::system
        Boost::variant2
        )
foreach (BOOST_YAML_DEPENDENCY ${BOOST_YAML_DEPENDENCIES})
    if (BOOST_YAML_DEPENDENCY MATCHES "^[ ]*Boost::([A-Za-z0-9_]+)[ ]*$")
        list(APPEND BOOST_YAML_INCLUDE_LIBRARIES ${CMAKE_MATCH_1})
    endif ()
endforeach ()

# Conditional dependencies
if (BUILD_TESTING OR BOOST_YAML_BUILD_TESTS)
    set(BOOST_YAML_UNIT_TEST_LIBRARIES container)
endif()

# Complete dependency list
set(BOOST_INCLUDE_LIBRARIES ${BOOST_YAML_INCLUDE_LIBRARIES} ${BOOST_YAML_UNIT_TEST_LIBRARIES})
set(BOOST_EXCLUDE_LIBRARIES yaml)

#-------------------------------------------------
#
# Add Boost Subdirectory
#
#-------------------------------------------------
if (BOOST_YAML_IS_ROOT)
    set(CMAKE_FOLDER Dependencies)
    # Find absolute BOOST_SRC_DIR
    if (NOT IS_ABSOLUTE ${BOOST_SRC_DIR})
        set(BOOST_SRC_DIR "${CMAKE_CURRENT_SOURCE_DIR}/${BOOST_SRC_DIR}")
    endif ()

    # Validate BOOST_SRC_DIR
    set(BOOST_SRC_DIR_IS_VALID ON)
    foreach (F "CMakeLists.txt" "Jamroot" "boost-build.jam" "bootstrap.sh" "libs")
        if (NOT EXISTS "${BOOST_SRC_DIR}/${F}")
            message(STATUS "${BOOST_SRC_DIR}/${F} does not exist. Fallback to find_package.")
            set(BOOST_SRC_DIR_IS_VALID OFF)
            break()
        endif ()
    endforeach ()

    # Create Boost interface targets
    if (BOOST_SRC_DIR_IS_VALID)
        # From BOOST_SRC_DIR
        if (BUILD_SHARED_LIBS)
            set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
        endif()
        set(BOOST_EXCLUDE_LIBRARIES ${PROJECT_NAME})
        set(PREV_BUILD_TESTING ${BUILD_TESTING})
        set(BUILD_TESTING OFF CACHE BOOL "Build the tests." FORCE)
        add_subdirectory(${BOOST_SRC_DIR} Dependencies/boost EXCLUDE_FROM_ALL)
        set(BUILD_TESTING ${PREV_BUILD_TESTING} CACHE BOOL "Build the tests." FORCE)
        set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${BOOST_SRC_DIR}/tools/cmake/include")
    else ()
        # From Boost Package
        find_package(Boost REQUIRED COMPONENTS system)
        foreach (BOOST_INCLUDE_LIBRARY ${BOOST_INCLUDE_LIBRARIES})
            if (NOT TARGET Boost::${BOOST_INCLUDE_LIBRARY})
                add_library(Boost::${BOOST_INCLUDE_LIBRARY} ALIAS Boost::headers)
            endif ()
        endforeach ()
    endif ()
    unset(CMAKE_FOLDER)
endif ()

#-------------------------------------------------
#
# Library
#
#-------------------------------------------------
file(GLOB_RECURSE BOOST_YAML_HEADERS CONFIGURE_DEPENDS include/boost/*.hpp)
file(GLOB_RECURSE BOOST_YAML_SOURCES CONFIGURE_DEPENDS src/*.cpp)
set_property(GLOBAL PROPERTY USE_FOLDERS ON)
source_group(TREE ${CMAKE_CURRENT_SOURCE_DIR}/include/boost PREFIX "" FILES ${BOOST_YAML_HEADERS})
source_group(TREE ${CMAKE_CURRENT_SOURCE_DIR}/src PREFIX "yaml" FILES ${BOOST_YAML_SOURCES})

function(boost_yaml_setup_properties target)
    target_compile_features(${target} PUBLIC cxx_std_11)
    target_compile_definitions(${target} PUBLIC BOOST_YAML_NO_LIB=1)
    target_include_directories(${target} PUBLIC "${PROJECT_SOURCE_DIR}/include")
    target_link_libraries(${target} PUBLIC ${BOOST_YAML_DEPENDENCIES})
    target_compile_definitions(${target} PUBLIC $<IF:$<BOOL:${BUILD_SHARED_LIBS}>,BOOST_YAML_DYN_LINK=1,BOOST_YAML_STATIC_LINK=1>)
    target_compile_definitions(${target} PRIVATE BOOST_YAML_SOURCE)
endfunction()

add_library(boost_yaml ${BOOST_YAML_HEADERS} ${BOOST_YAML_SOURCES})
add_library(Boost::yaml ALIAS boost_yaml)
boost_yaml_setup_properties(boost_yaml)

#-------------------------------------------------
#
# Tests
#
#-------------------------------------------------
if (BUILD_TESTING OR BOOST_YAML_BUILD_TESTS)
    if (BOOST_YAML_IS_ROOT)
        include(CTest)
    endif ()
    add_subdirectory(extra/test_suite)
    add_subdirectory(test)
endif ()

#-------------------------------------------------
#
# Examples
#
#-------------------------------------------------
if (BOOST_YAML_BUILD_EXAMPLES)
    add_subdirectory(example)
endif ()