build.gradle

import java.util.regex.Matcher

plugins {
    id 'java'
}

repositories {
    mavenCentral()
    maven { url 'https://jitpack.io' }
}

dependencies {
    implementation files("libs/craftbukkit-1060.jar")
    implementation files("libs/Essentials.jar")
    implementation 'com.github.zavdav:ZCore:1.0.0-rc1'
}

File ymlFile = file('src/main/resources/plugin.yml') as File

if (!ymlFile.exists()) {
    throw new GradleException("The 'plugin.yml' file does not exist in 'src/main/resources'.")
}

String ymlText = ymlFile.text
Matcher mainMatcher = (ymlText =~ /main:\s*(\S+)/)
Matcher versionMatcher = (ymlText =~ /version:\s*(\S+)/)
Matcher nameMatcher = (ymlText =~ /name:\s*(\S+)/)

if (!mainMatcher.find()) {
    throw new GradleException("The 'main' attribute wasn't found in the 'plugin.yml' file.")
}

if (versionMatcher.find()) {
    version = versionMatcher.group(1)
} else {
    throw new GradleException("The 'version' attribute wasn't found in the 'plugin.yml' file.")
}

if (!nameMatcher.find()) {
    throw new GradleException("The 'name' attribute wasn't found in the 'plugin.yml' file.")
}

tasks.named('build') {
    mustRunAfter 'clean'
}

tasks.register('cleanBuild') {
    dependsOn 'clean', 'build'
    group = 'custom'
}

jar {
    manifest {
        attributes(
                'Implementation-Title': "${project.name}",
                'Implementation-Version': "${project.version}"
        )
    }

    archiveFileName = "${project.name}-${project.version}.jar"
}