Middleware register issue.

[AdriaanBoshoff]

I'm having an issue where the middlware is running only for the POST endpoints and not running in the order its being declared.

• POST /v1/login - Should not have middleware but it does.
• GET /v1/getproducts - Should not have middleware and it doesn't
• GET /v1/test - Should have middlware but it doesn't

procedure TAPIEndpointsV1.RegisterEndpoints;
begin
  FController := THorse.Group.Prefix('/v1'); // REGISTER GROUP

  FController.Post('/login', Self.POST_Login); // Middleware runs but it shouldnt

  FController.Get('/getproducts', Self.GET_Products); // Middleware doesnt run

  FController.Use(Self.MW_ValidateSession); // Register Middleware

  FController.Get('/test', Self.GET_Test); // Middleware doesnt run but it should
end;

[viniciussanchez]

Please send us the complete example.

[AdriaanBoshoff]

I can't upload the code I was using but I did manage to make a test project.

I basically only want certain endpoints of the /v1 group to use middleware. Clearly I am doing it wrong. What would be the correct way to approach this?

Please see below code:

program pHorseTest;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  System.SysUtils,
  Horse,
  Horse.Core,
  Horse.Core.Group.Contract;

type
  TAPIEndpointsV1 = class
  private
    FController: IHorseCoreGroup<THorseCore>;
  private
    // Middleware
    procedure MW_TestMiddleware(Req: THorseRequest; Res: THorseResponse; Next: TProc);

    // Endpoints
    procedure GET_Test(Req: THorseRequest; Res: THorseResponse; Next: TProc);
    procedure POST_LOGIN(Req: THorseRequest; Res: THorseResponse; Next: TProc);
  public
    procedure RegisterEndpoints;
  end;

procedure Main;
begin

end;

{ TAPIEndpointsV1 }

procedure TAPIEndpointsV1.GET_Test(Req: THorseRequest; Res: THorseResponse; Next: TProc);
begin
  Res.Status(200).Send('TEST');
end;

procedure TAPIEndpointsV1.MW_TestMiddleware(Req: THorseRequest; Res: THorseResponse; Next: TProc);
begin
  Res.Status(200).Send('Middleware took over');

  raise EHorseCallbackInterrupted.Create;
end;

procedure TAPIEndpointsV1.POST_LOGIN(Req: THorseRequest; Res: THorseResponse; Next: TProc);
begin
  Res.Status(200).Send('LOGIN');
end;

procedure TAPIEndpointsV1.RegisterEndpoints;
begin
  FController := THorse.Group.Prefix('/v1');

  FController.Get('/test1', Self.GET_Test);  // Should NOT have middleware

  FController.Post('/login', Self.POST_LOGIN); // Should NOT have middleware

  FController.Use(Self.MW_TestMiddleware);  // Register Middleware

  FController.Get('/test2', Self.GET_Test);  // Should have middleware
end;

begin
  try
    var api := TAPIEndpointsV1.Create;
    try
      api.RegisterEndpoints;

      THorse.Port := 8080;
      THorse.Host := '0.0.0.0';
      THorse.Listen(
        procedure // Started Listening
        begin
          Writeln('Listening...');
        end,
        procedure // Stopped Listening
        begin
          Writeln('Stopped...');
        end);
    finally
      api.Free;
    end;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;

  WriteLn('PROGRAM END.');
  ReadLn;
end.

[daviddev16]

As far as I know, middleware always executes earlier than any route, regardless of in which order it was registered. Although, I am not sure if this is the expected behavior.

Here is a simple workaround for this problem.

procedure TAPIEndpointsV1.MW_TestMiddleware(Req: THorseRequest; Res: THorseResponse; Next: TProc);
begin
  // Skips the middleware processing.
  if not Req.PathInfo.EndsWith('/test2') then
  begin
    Next; Exit;
  end;

  Res.Status(200).Send('Middleware took over');

  raise EHorseCallbackInterrupted.Create;
end;

Hope it helps.