roslin.config

//Profile config names for nf-core/configs
params {
    config_profile_description = 'University of Edinburgh (Eddie) cluster profile for Roslin Institute provided by nf-core/configs.'
    config_profile_contact     = 'Sebastien Guizard (@sguizard) and Donald Dunbar (@donalddunbar)'
    config_profile_url         = 'https://www.ed.ac.uk/information-services/research-support/research-computing/ecdf/high-performance-computing'
}

executor {
    name = "sge"
}

process {
    stageInMode = 'symlink'
    scratch     = 'false'
    penv        = { task.cpus > 1 ? "sharedmem" : null }

    // This will override all jobs clusterOptions
    clusterOptions = {
        def memoryPerCpu = task.memory.toMega() / task.cpus
        def nodeExclusion = System.getenv('NFX_NODE_EXCLUSION') ?
            "-l h=!(${System.getenv('NFX_NODE_EXCLUSION')})" :
            ""
        def projectCode = System.getenv('NFX_SGE_PROJECT') ?
            "${System.getenv('NFX_SGE_PROJECT')}" :
            "uoe_baseline"

        "-l h_rss=${memoryPerCpu}M -P ${projectCode} ${nodeExclusion}"
    }

    // common SGE error statuses
    errorStrategy = {task.exitStatus in [143,137,104,134,139,140] ? 'retry' : 'finish'}
    maxErrors = '-1'
    maxRetries = 3

    // Use apptainer module instead of singularity
    beforeScript =
    """
    . /etc/profile.d/modules.sh
    module load igmm/apps/apptainer/1.3.4
    export SINGULARITY_TMPDIR="\$TMPDIR"
    """
}

env {
    MALLOC_ARENA_MAX=1
}

singularity {
    envWhitelist = "SINGULARITY_TMPDIR,TMPDIR"
    runOptions   = '-p -B "$TMPDIR"'
    enabled      = true
    autoMounts   = true
    // Define the singularity cache directory depending on the presence of the NFX_SGE_PROJECT variable
    // User without compute project can't access to the shared cache directory.
    // So, they need to store singularity images into the work directory.
    cacheDir     = System.getenv('NFX_SGE_PROJECT') ?
        "/exports/cmvm/eddie/eb/groups/alaw3_eb_singularity_cache" :
        null
}